steeef.zsh-theme

# Zsh steeef theme as a standalone repository. The purpose behind this repo is avoid having a
# dependency on oh-my-zsh when using the steeef theme. Zsh plugin managers such as Antibody can use
# the theme without having to integrate oh-my-zsh. Credits to the original theme authors.
# For more info on prompt expansion see http://zsh.sourceforge.net/Doc/Release/Prompt-Expansion.html

# prompt style and colors based on Steve Losh's Prose theme:
# http://github.com/sjl/oh-my-zsh/blob/master/themes/prose.zsh-theme
#
# vcs_info modifications from Bart Trojanowski's zsh prompt:
# http://www.jukie.net/bart/blog/pimping-out-zsh-prompt
#
# git untracked files modification from Brian Carper:
# http://briancarper.net/blog/570/git-info-in-your-zsh-prompt

function k8s_info {
  if [ -f ~/.kube/config ]; then
    k8s_context=$(cat ~/.kube/config | grep "current-context:" | sed "s/current-context: //")
    if [ ! -z $k8s_context ]; then
      echo " %F{135}(k8s: $k8s_context)"
    fi
  fi
}

function aws_info {
  if [ ! -z $AWS_PROFILE ]; then
    echo " %F{111}(aws: $AWS_PROFILE)"
  fi
}

setopt prompt_subst

autoload -U add-zsh-hook
autoload -Uz vcs_info

#use extended color pallete if available
if [[ $terminfo[colors] -ge 256 ]]; then
    turquoise="%F{81}"
    orange="%F{166}"
    purple="%F{135}"
    hotpink="%F{161}"
    limegreen="%F{118}"
else
    turquoise="%F{cyan}"
    orange="%F{yellow}"
    purple="%F{magenta}"
    hotpink="%F{red}"
    limegreen="%F{green}"
fi

# enable VCS systems you use
zstyle ':vcs_info:*' enable git svn

# check-for-changes can be really slow.
# you should disable it, if you work with large repositories
zstyle ':vcs_info:*:prompt:*' check-for-changes true

# set formats
# %b - branchname
# %u - unstagedstr (see below)
# %c - stagedstr (see below)
# %a - action (e.g. rebase-i)
# %R - repository path
# %S - path in the repository
PR_RST="%f"
FMT_BRANCH="(%{$turquoise%}%b%u%c${PR_RST})"
FMT_ACTION="(%{$limegreen%}%a${PR_RST})"
FMT_UNSTAGED="%{$orange%}●"
FMT_STAGED="%{$limegreen%}●"

zstyle ':vcs_info:*:prompt:*' unstagedstr   "${FMT_UNSTAGED}"
zstyle ':vcs_info:*:prompt:*' stagedstr     "${FMT_STAGED}"
zstyle ':vcs_info:*:prompt:*' actionformats "${FMT_BRANCH}${FMT_ACTION}"
zstyle ':vcs_info:*:prompt:*' formats       "${FMT_BRANCH}"
zstyle ':vcs_info:*:prompt:*' nvcsformats   ""

function steeef_precmd {
    # check for untracked files or updated submodules, since vcs_info doesn't
    if git ls-files --other --exclude-standard 2> /dev/null | grep -q "."; then
        PR_GIT_UPDATE=1
        FMT_BRANCH="(%{$turquoise%}%b%u%c%{$hotpink%}●${PR_RST})"
    else
        FMT_BRANCH="(%{$turquoise%}%b%u%c${PR_RST})"
    fi
    zstyle ':vcs_info:*:prompt:*' formats " ${FMT_BRANCH}"

    vcs_info 'prompt'
}
add-zsh-hook precmd steeef_precmd

pr_24h_clock=' %*'

PROMPT=$'
%{$purple%}%n${PR_RST}@%{$orange%}%m${PR_RST} %{$limegreen%}%~${PR_RST}$vcs_info_msg_0_$(k8s_info)$(aws_info)%{$orange%}$pr_24h_clock${PR_RST}
$ '