Add URL type to Framework (#726)

* Add URL type to Framework

* typo

* Changed Url from object

* Update sui_programmability/framework/tests/UrlTests.move

Co-authored-by: Sam Blackshear <sam@mystenlabs.com>

* Update sui_programmability/framework/sources/Url.move

Co-authored-by: Sam Blackshear <sam@mystenlabs.com>

* Update sui_programmability/framework/sources/Url.move

Co-authored-by: Sam Blackshear <sam@mystenlabs.com>

* Revert use constant in abort code

Co-authored-by: Sam Blackshear <sam@mystenlabs.com>

sui_programmability/framework/sources/Url.move

@@ -0,0 +1,75 @@
+/// URL: standard Uniform Resource Locator string
+/// Url: Sui type which wraps a URL
+/// UrlCommitment: Sui type which wraps a Url but also includes an immutable commitment
+/// to the hash of the resource at the given URL
+module Sui::Url {
+    use Std::ASCII::String;
+    use Std::Vector;
+
+    /// Length of the vector<u8> representing a resource hash
+    const HASH_VECTOR_LENGTH: u64 = 32;
+
+    /// Error code when the length of the hash vector is not HASH_VECTOR_LENGTH
+    const EHASH_LENGTH_MISMATCH: u64 = 0;
+
+    /// Represents an arbitrary URL. Clients rendering values of this type should fetch the resource at `url` and render it using a to-be-defined Sui standard.
+    struct Url has store, drop {
+        // TODO: validate URL format
+        url: String,
+    }
+
+    /// Represents an arbitrary URL plus an immutable commitment to the underlying
+    /// resource hash. Clients rendering values of this type should fetch the resource at `url`, and then compare it against `resource_hash` using a to-be-defined Sui standard, and (if the two match) render the value using the `Url` standard.
+    struct UrlCommitment has store, drop {
+        url: Url,
+        resource_hash: vector<u8>,
+    }
+
+
+    // === constructors ===
+
+    /// Create a `Url`, with no validation
+    public fun new_unsafe_url(url: String): Url {
+        Url { url }
+    }
+
+    /// Create a `UrlCommitment`, and set the immutable hash
+    public fun new_unsafe_url_commitment(url: Url, resource_hash: vector<u8>): UrlCommitment {
+        // Length must be exact
+        assert!(Vector::length(&resource_hash) == HASH_VECTOR_LENGTH, EHASH_LENGTH_MISMATCH);
+
+        UrlCommitment { url, resource_hash }
+    }
+
+
+    // === `Url` functions ===
+
+    /// Get inner URL
+    public fun inner_url(self: &Url): String{
+        self.url
+    }
+
+    /// Update the inner URL
+    public fun update(self: &mut Url, url: String) {
+        self.url = url;
+    }
+
+
+    // === `UrlCommitment` functions ===
+
+    /// Get the hash of the resource at the URL
+    /// We enforce that the hash is immutable
+    public fun url_commitment_resource_hash(self: &UrlCommitment): vector<u8> {
+        self.resource_hash
+    }
+
+    /// Get inner URL
+    public fun url_commitment_inner_url(self: &UrlCommitment): String{
+        self.url.url
+    }
+
+    /// Update the URL, but the hash of the object at the URL must never change
+    public fun url_commitment_update(self: &mut UrlCommitment, url: String) {
+        update(&mut self.url, url)
+    }
+}

sui_programmability/framework/tests/UrlTests.move

@@ -0,0 +1,48 @@
+#[test_only]
+module Sui::UrlTests {
+    use Sui::Url;
+    use Std::ASCII::Self;
+
+    const EHASH_LENGTH_MISMATCH: u64 = 0;
+    const URL_STRING_MISMATCH: u64 = 1;
+
+    #[test]
+    fun test_basic_url() {
+        // url strings are not currently validated
+        let url_str = ASCII::string(x"414243454647");
+
+        let url = Url::new_unsafe_url(url_str);
+        assert!(Url::inner_url(&url) == url_str, URL_STRING_MISMATCH);
+    }
+
+    #[test]
+    #[expected_failure(abort_code = 0)]
+    fun test_malformed_hash() {
+        // url strings are not currently validated
+        let url_str = ASCII::string(x"414243454647");
+        // length too short
+        let hash = x"badf012345";
+
+        let url = Url::new_unsafe_url(url_str);
+        let _ = Url::new_unsafe_url_commitment(url, hash);
+    }
+
+    #[test]
+    fun test_good_hash() {
+        // url strings are not currently validated
+        let url_str = ASCII::string(x"414243454647");
+        // 32 bytes
+        let hash = x"1234567890123456789012345678901234567890abcdefabcdefabcdefabcdef";
+
+        let url = Url::new_unsafe_url(url_str);
+        let url_commit = Url::new_unsafe_url_commitment(url, hash);
+
+        assert!(Url::url_commitment_resource_hash(&url_commit) == hash, EHASH_LENGTH_MISMATCH);
+        assert!(Url::url_commitment_inner_url(&url_commit) == url_str, URL_STRING_MISMATCH);
+
+        let url_str = ASCII::string(x"37414243454647");
+
+        Url::url_commitment_update(&mut url_commit, url_str);
+        assert!(Url::url_commitment_inner_url(&url_commit) == url_str, URL_STRING_MISMATCH);
+    }
+}