Merge pull request #84 from commercialhaskell/template

Add a template

Author: snoyberg

etc/.gitignore

@@ -0,0 +1 @@
+/rio.hsfiles

etc/make-template.hs

@@ -0,0 +1,81 @@
+#!/usr/bin/env stack
+{- stack runghc
+    --package rio
+    --package conduit
+    --package project-template
+    -- -hide-all-packages
+-}
+{-# LANGUAGE NoImplicitPrelude #-}
+{-# LANGUAGE OverloadedStrings #-}
+{-# LANGUAGE RecordWildCards   #-}
+import Conduit
+import RIO
+import qualified RIO.ByteString as B
+import qualified RIO.ByteString.Lazy as BL
+import RIO.FilePath
+import RIO.Process
+import qualified RIO.Text as T
+import qualified RIO.Text.Partial as T (replace)
+import RIO.Time
+import Text.ProjectTemplate
+
+data App = App
+  { appLogFunc :: !LogFunc
+  , appProcessContext :: !ProcessContext
+  }
+
+instance HasLogFunc App where
+  logFuncL = lens appLogFunc (\x y -> x { appLogFunc = y })
+instance HasProcessContext App where
+  processContextL = lens appProcessContext (\x y -> x { appProcessContext = y })
+
+start :: RIO App a -> IO a
+start inner = do
+  appProcessContext <- mkDefaultProcessContext
+  lo <- logOptionsHandle stderr True
+  withLogFunc lo $ \appLogFunc -> runRIO App {..} inner
+
+splitNulls :: ByteString -> [ByteString]
+splitNulls bs
+  | B.null bs = []
+  | otherwise =
+      let (x, y) = B.break (== 0) bs
+       in x : splitNulls (B.drop 1 y)
+
+decode :: ByteString -> RIO App FilePath
+decode bs =
+  case decodeUtf8' bs of
+    Left e -> throwIO e
+    Right x -> return $ T.unpack x
+
+readReplace :: MonadIO m => FilePath -> m ByteString
+readReplace fp = do
+  (year, _, _) <- toGregorian . utctDay <$> getCurrentTime
+  (encodeUtf8 . replaces year) <$> readFileUtf8 fp
+  where
+    replaces year
+      = T.replace "PROJECTNAME" "{{name}}"
+      . T.replace "AUTHOR" "{{author-name}}{{^author-name}}Author name here{{/author-name}}"
+      . T.replace "MAINTAINER" "{{author-email}}{{^author-email}}example@example.com{{/author-email}}"
+      . T.replace "GITHUB" "{{github-username}}{{^github-username}}githubuser{{/github-username}}/{{name}}"
+      . T.replace "DESCRIPTION" "Please see the README on Github at <https://github.com/{{github-username}}{{^github-username}}githubuser{{/github-username}}/{{name}}#readme>"
+      . T.replace "COPYRIGHT"
+          (T.concat
+             [ "{{copyright}}{{^copyright}}{{year}}{{^year}}"
+             , T.pack $ show year
+             , "{{/year}} {{author-name}}{{^author-name}}Author name here{{/author-name}}{{/copyright}}"
+             ])
+
+main :: IO ()
+main = start $ do
+  let templatedir = "template"
+
+  -- Make sure it passes
+  proc "stack" ["test"] runProcess_
+
+  rawout <- withWorkingDir templatedir
+          $ proc "git" ["ls-files", "-z"]
+            readProcessStdout_
+  files <- mapM decode $ splitNulls $ BL.toStrict rawout
+  let src = forM_ files $ \fp -> yield (fp, readFileBinary $ templatedir </> fp)
+  runConduitRes $ src .| createTemplate .| sinkFile "rio.hsfiles"

etc/stack.yaml

@@ -0,0 +1,5 @@
+resolver: lts-11.5
+packages:
+- template
+extra-deps:
+- ../rio

etc/template/.gitignore

@@ -0,0 +1,5 @@
+*.cabal
+*~
+*.swp
+tarballs/
+.stack-work/

etc/template/ChangeLog.md

@@ -0,0 +1,3 @@
+# Changelog for PROJECTNAME
+
+## Unreleased changes

etc/template/LICENSE

@@ -0,0 +1,30 @@
+Copyright AUTHOR (c) 2018
+
+All rights reserved.
+
+Redistribution and use in source and binary forms, with or without
+modification, are permitted provided that the following conditions are met:
+
+    * Redistributions of source code must retain the above copyright
+      notice, this list of conditions and the following disclaimer.
+
+    * Redistributions in binary form must reproduce the above
+      copyright notice, this list of conditions and the following
+      disclaimer in the documentation and/or other materials provided
+      with the distribution.
+
+    * Neither the name of Author name here nor the names of other
+      contributors may be used to endorse or promote products derived
+      from this software without specific prior written permission.
+
+THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+"AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
+A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
+OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
+SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
+LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
+DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
+THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
+(INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
+OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.

etc/template/README.md

@@ -0,0 +1 @@
+# PROJECTNAME

etc/template/Setup.hs

@@ -0,0 +1,2 @@
+import Distribution.Simple
+main = defaultMain

etc/template/app/Main.hs

@@ -0,0 +1,32 @@
+{-# LANGUAGE NoImplicitPrelude #-}
+{-# LANGUAGE TemplateHaskell #-}
+module Main (main) where
+
+import Import
+import Run
+import RIO.Process
+import Options.Applicative.Simple
+import qualified Paths_PROJECTNAME
+
+main :: IO ()
+main = do
+  (options, ()) <- simpleOptions
+    $(simpleVersion Paths_PROJECTNAME.version)
+    "Header for command line arguments"
+    "Program description, also for command line arguments"
+    (Options
+       <$> switch ( long "verbose"
+                 <> short 'v'
+                 <> help "Verbose output?"
+                  )
+    )
+    empty
+  lo <- logOptionsHandle stderr (optionsVerbose options)
+  pc <- mkDefaultProcessContext
+  withLogFunc lo $ \lf ->
+    let app = App
+          { appLogFunc = lf
+          , appProcessContext = pc
+          , appOptions = options
+          }
+     in runRIO app run

etc/template/package.yaml

@@ -0,0 +1,51 @@
+name:                PROJECTNAME
+version:             0.1.0.0
+github:              GITHUB
+license:             BSD3
+author:              AUTHOR
+maintainer:          MAINTAINER
+copyright:           COPYRIGHT
+
+extra-source-files:
+- README.md
+- ChangeLog.md
+
+# Metadata used when publishing your package
+# synopsis:            Short description of your package
+# category:            Web
+
+# To avoid duplicated efforts in documentation and dealing with the
+# complications of embedding Haddock markup inside cabal files, it is
+# common to point users to the README.md file.
+description:         DESCRIPTION
+
+dependencies:
+- base >= 4.10 && < 10
+- rio >= 0.1.1.0
+
+library:
+  source-dirs: src
+
+executables:
+  PROJECTNAME-exe:
+    main:                Main.hs
+    source-dirs:         app
+    ghc-options:
+    - -threaded
+    - -rtsopts
+    - -with-rtsopts=-N
+    dependencies:
+    - PROJECTNAME
+    - optparse-simple
+
+tests:
+  PROJECTNAME-test:
+    main:                Spec.hs
+    source-dirs:         test
+    ghc-options:
+    - -threaded
+    - -rtsopts
+    - -with-rtsopts=-N
+    dependencies:
+    - PROJECTNAME
+    - hspec

etc/template/src/Import.hs

@@ -0,0 +1,8 @@
+{-# LANGUAGE NoImplicitPrelude #-}
+module Import
+  ( module RIO
+  , module Types
+  ) where
+
+import RIO
+import Types

etc/template/src/Run.hs

@@ -0,0 +1,9 @@
+{-# LANGUAGE NoImplicitPrelude #-}
+{-# LANGUAGE OverloadedStrings #-}
+module Run (run) where
+
+import Import
+
+run :: RIO App ()
+run = do
+  logInfo "We're inside the application!"

etc/template/src/Types.hs

@@ -0,0 +1,22 @@
+{-# LANGUAGE NoImplicitPrelude #-}
+module Types where
+
+import RIO
+import RIO.Process
+
+-- | Command line arguments
+data Options = Options
+  { optionsVerbose :: !Bool
+  }
+
+data App = App
+  { appLogFunc :: !LogFunc
+  , appProcessContext :: !ProcessContext
+  , appOptions :: !Options
+  -- Add other app-specific configuration information here
+  }
+
+instance HasLogFunc App where
+  logFuncL = lens appLogFunc (\x y -> x { appLogFunc = y })
+instance HasProcessContext App where
+  processContextL = lens appProcessContext (\x y -> x { appProcessContext = y })

etc/template/src/Util.hs

@@ -0,0 +1,11 @@
+{-# LANGUAGE NoImplicitPrelude #-}
+-- | Silly utility module, used to demonstrate how to write a test
+-- case.
+module Util
+  ( plus2
+  ) where
+
+import RIO
+
+plus2 :: Int -> Int
+plus2 = (+ 2)

etc/template/test/Spec.hs

@@ -0,0 +1 @@
+{-# OPTIONS_GHC -F -pgmF hspec-discover #-}

etc/template/test/UtilSpec.hs

@@ -0,0 +1,14 @@
+{-# LANGUAGE NoImplicitPrelude #-}
+module UtilSpec (spec) where
+
+import Import
+import Util
+import Test.Hspec
+import Test.Hspec.QuickCheck
+
+spec :: Spec
+spec = do
+  describe "plus2" $ do
+    it "basic check" $ plus2 0 `shouldBe` 2
+    it "overflow" $ plus2 maxBound `shouldBe` minBound + 1
+    prop "minus 2" $ \i -> plus2 i - 2 `shouldBe` i